Data Analysis Examples

Amount of writing by Related-Major Category

To estimate the number of pages of assigned writing, the average number of writing assignments of a given page-length was multiplied by an approximate number of pages for the assignment type (see Estimating Number of Pages Written for calculation details).

Average Number of Written Pages by Related-Major Category (NSSE 2014)
First-YearSenior
Arts & Humanities4981
Biological Sciences, Agriculture, & Natural Resources4766
Physical Sciences, Mathematics, & Computer Science4456
Social Sciences5289
Business4873
Communications, Media, & Public Relations5081
Education4684
Engineering4688
Health Professions4369
Social Service Professions4787

*********************************************************.
WRITING BY MAJOR FIELD CATEGORY.
*********************************************************.

***** ESTIMATED PAGES OF ASSIGNED WRITING.

RECODE wrshort (1=0) (2=4.5) (3=12) (4=24) (5=39) (6=54) (7=69) INTO wr1.
RECODE wrmed (1=0) (2=12) (3=32) (4=64) (5=104) (6=144) (7=184) INTO wr2.
RECODE wrlong (1=0) (2=22.5) (3=60) (4=120) (5=195) (6=270) (7=345) INTO wr3.
EXECUTE.

COMPUTE wrpages=wr1+wr2+wr3.
VARIABLE LEVEL wrpages (SCALE).
VARIABLE LABELS wrpages 'Estimated pages of assigned writing'.
EXECUTE.
DELETE VARIABLES wr1 wr2 wr3.

*****CREATE TABLES BY MAJOR FIELD CATEGORY.
CTABLES
/VLABELS VARIABLES=MAJfirstcol IRclass wrpages DISPLAY=DEFAULT
/TABLE MAJfirstcol [C] BY IRclass [C] > wrpages [S][COUNT MEAN]
/CATEGORIES VARIABLES=MAJfirstcol ORDER=A KEY=VALUE EMPTY=INCLUDE
/CATEGORIES VARIABLES=IRclass [1, 4] EMPTY=INCLUDE.

 

 

Engagement with Faculty by Sex and Class Level

The following table presents the percentage of students who frequently (Very often or Often) engaged with faculty in various types of activities arrayed by institution-provided sex and class level information.

Percentage of Students who Very Often or Often Engaged with Faculty by Sex and Class (NSSE 2014)
First-YearSenior
FemalesMalesFemalesMales
Talked about career plans with a faculty member34%32%47%43%
Worked with a faculty member on activities other than coursework (committees, student groups, etc.)18%21%29%30%
Discussed course topics, ideas, or concepts with a faculty member outside of class25%29%35%39%
Discussed your academic performance with a faculty member29%31%36%34%
*********************************************************.
NSSE SAMPLE ANALYSES AND SYNTAX
--FACULTY ENGAGEMENT BY SEX AND CLASS LEVEL.
*********************************************************.

*********************************************************.
****RECODE INTO 'FREQUENTLY' EXPERIENCED .

RECODE SFcareer SFotherwork SFdiscuss SFperform (1, 2 = 0) (3, 4 = 1)
INTO fSFcareer fSFotherwork fSFdiscuss fSFperform.

VALUE LABELS fSFcareer fSFotherwork fSFdiscuss fSFperform 0 'Infrequently' 1 'Frequently'.

VARIABLE LEVEL fSFcareer fSFotherwork fSFdiscuss fSFperform (ordinal).

FREQUENCIES fSFcareer fSFotherwork fSFdiscuss fSFperform.


****CREATE TABLE USING CTABLES COMMAND.
****.
****NOTE: If using NSSE 2013 data replace 'IRsex' with 'IRgender'.
****.

CTABLES
/VLABELS VARIABLES=fSFcareer fSFotherwork fSFdiscuss fSFperform IRclass IRsex DISPLAY=DEFAULT
/TABLE (fSFcareer + fSFotherwork + fSFdiscuss + fSFperform) [COUNT COLPCT F4.0] BY IRclass > IRsex
/CATEGORIES VARIABLES = fSFcareer fSFotherwork fSFdiscuss fSFperform IRsex ORDER=A KEY=VALUE
EMPTY=INCLUDE
/CATEGORIES VARIABLES = IRclass [1, 4] EMPTY=INCLUDE.


****CREATE PERCENTAGES USING FREQUENCIES COMMAND.
****VALID PERCENT MATCHES CTABLE

**FIRST-YEAR FEMALE.
TEMPORARY.
SELECT IF (IRclass eq 1 and IRsex eq 0).
FREQUENCIES fSFcareer fSFotherwork fSFdiscuss fSFperform.

**FIRST-YEAR MALE.
TEMPORARY.
SELECT IF (IRclass eq 1 and IRsex eq 1).
FREQUENCIES fSFcareer fSFotherwork fSFdiscuss fSFperform.

**SENIOR FEMALE.
TEMPORARY.
SELECT IF (IRclass eq 4 and IRsex eq 0).
FREQUENCIES fSFcareer fSFotherwork fSFdiscuss fSFperform.

**SENIOR MALE.
TEMPORARY.
SELECT IF (IRclass eq 4 and IRsex eq 1).
FREQUENCIES fSFcareer fSFotherwork fSFdiscuss fSFperform.

High-Impact Practices

Because of their positive effects on student learning and retention, undergraduate opportunities such as learning communities, service-learning, research with a faculty member, study abroad, internships, and culminating senior experiences are called high-impact practices (Kuh, 2008). High-impact practices share several traits: They demand considerable time and effort, provide learning opportunities outside of the classroom, require meaningful interactions with faculty and students, encourage interaction with diverse others, and provide frequent and meaningful feedback. Participation in these activities can be life-changing.

The table below displays the percentage of first-year students and seniors who participated in selected high-impact practices by several student characteristics. The syntax linked above can be used to recreate this summary table with your own institution's data. From these results, you can compare participation in high-impact practices across a variety of student characteristics.

Participation in High-Impact Practices by Student Characteristics (NSSE 2014)
First-Year StudentsSeniors
Learning
Community
Service-
Learning
Research
with
Faculty
Learning
Community
Service-
Learning
Research
with
Faculty
Internship/
Field Exp.
Study
Abroad
Culminating
Experience
Sexa
Female16515276525541747
Male14526235727491247
Race/ethnicity or internationala
American Indian or Alaska Native18567276925491143
Asian14565236622471238
Black or African American1855729682247943
Hispanic or Latino15555246421461138
Native Hawaiian/ Other Pacific Islander11566286924461037
White15495256127551649
Other165313156118332052
Foreign or nonresident alien14669247226432443
Two or more races/ ethnicities18536266227531649
Age
Traditional (First-year < 21, Senior < 25)16525296431602053
Nontraditional (First-year 21+, Senior 25+)946717581636535
First-generation statusb
Not first-generation16506276030582051
First-generation1454623632146942
Enrollment statusa
Part-time943516561435633
Full-time16526276328561750
Residence
Living off campus12526246124501344
Living on campus17515346338652762
Major categoryc
Arts & humanities15475235428462559
Biological sciences, agriculture, natural resources17498265447551745
Physical sciences, math, computer science14447204241471144
Social sciences15495236034502148
Business15545225713441443
Communications, media, public relations18515266622672057
Education16624378217691250
Engineering18476274834581260
Health professions1557530802055938
Social service professionals1457527711854939
Undecided/ undeclared12474196516301124
Overall
15526256226521547

Note: Participating students are those who responded "Done or in progress" for all HIPs except service-learning, where students reported at least "Some" of their courses included a community-based project. 
a. Institution-reported variable
b. Neither parent holds a bachelor's degree
c. NSSE's default related-major categories, based on students' reported major or expected major (first reported major for double majors). Excludes majors categorized as "all other."

For more information on these results and other ideas for using your NSSE results, see the 2014 NSSE Annual Results and Lessons from the Field.

Kuh, G. D. (2008). High-impact educational practices: What they are, who has access to them, and why they matter. Washington, DC: Association of American Colleges and Universities.

*********************************************************.
HIGH-IMPACT PRACTICES BY STUDENT CHARACTERISTICS
This syntax will recreate the Percent Participation in High-Impact Practices by Student
Characteristics table in the High-Impact Practices report.
*********************************************************.

*********************************************************.
***** RECODE AND FLAG PARTICIPATION IN HIGH-IMPACT PRACTICES.

RECODE intern leader learncom abroad research capstone (1, 2, 3 = 0) (4 = 1) INTO
internR leaderR learncomR abroadR researchR capstoneR.
VALUE LABELS internR leaderR learncomR abroadR researchR capstoneR 0 'Not Done' 1 'Done or in progress'.
RECODE servcourse (4, 3, 2=1) (1=0) INTO servcourseR.
VALUE LABELS servcourseR 0 'None' 1 'At least some'.
EXECUTE.

*********************************************************.
***** RECODE AGE INTO TRADITIONAL AGE AND NOT TRADITIONAL AGE.
NUMERIC dAge (F4.0).
VARIABLE LABELS dAge 'Flag for traditionally aged students (>15; <21 for FY, <25 for SR)'.
VALUE LABELS dAge 0 'Not traditional age' 1 'Traditional age (>15; <21 for FY, <25 for SR)'.
RECODE age (SYSMIS=SYSMIS) (ELSE=0) INTO dAge.
EXECUTE.
IF (IRclass=1 AND age GE 16 AND age LT 21) dAge=1.
IF (IRclass=4 AND age GE 16 AND age LT 25) dAge=1.
EXECUTE.

*********************************************************.
***** RECODE LIVING INTO ON CAMPUS AND OFF CAMPUS.
NUMERIC oncampus (F4.0).
RECODE living (1 THRU 2 =1) (3 THRU 5=0) INTO oncampus.
VARIABLE LABELS oncampus 'Student living on campus (collapsed recode of living)'.
VALUE LABELS oncampus 0 'No' 1 'Yes'.
EXECUTE.

**** FOR CANADIAN INSTITUTIONS RECODE LIVING_CA TO ONCAMPUS.
IF (living_ca LE 2) oncampus=1.
IF (living_ca GE 3) oncampus=0.
EXECUTE.

*********************************************************.
***** CREATE FIRST-GENERATION STATUS.
NUMERIC firstgen (F4.0).
RECODE parented (1 thru 4=1) (5 thru 7=0) INTO firstgen.
VARIABLE LABELS firstgen "First-Generation Status (neither parent/guardian holds a bachelor's degree)".
FORMATS firstgen(F4.0).
VALUE LABELS firstgen 0 'No' 1 'Yes'.
EXECUTE.

**** FOR CANADIAN INSTITUTIONS RECODE PARENTED_CA TO FIRSTGEN.
IF (parented_ca LE 4) firstgen = 1.
IF (parented_ca GT 4) firstgen = 0.
EXECUTE.

*********************************************************.
***** SYNTAXT TO CREATE TABLE.
****NOTE: If using NSSE 2013 data replace 'IRsex' with 'IRgender'.

CTABLES /TABLE (IRsex + IRrace + dage + FirstGen + IRenrollment + oncampus + MAJfirstCol) [COUNT ROWPCT F4.0]
BY IRclass > (learncomR + servcourseR + researchR + internR + abroadR + capstoneR)
/CATEGORIES VARIABLES = IRsex IRrace dage FirstGen IRenrollment oncampus MAJfirstCol TOTAL=NO EMPTY=INCLUDE
/CATEGORIES VARIABLES = IRrace [1, 2, 3, 4, 5, 6, 7, 8, 9] EMPTY=INCLUDE
/CATEGORIES VARIABLES = dAge [1, 0] EMPTY=INCLUDE
/CATEGORIES VARIABLES = MAJfirstcol [1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 999] EMPTY=INCLUDE
/CATEGORIES VARIABLES = learncomR servcourseR researchR internR abroadR capstoneR [0, 1, SUBTOTAL].

The Relationship of Residence Life with Selected Engagement Measures

Successful residence life programs create an environment that promotes "seamless learning environments" (Kuh, 1996) with both curricular and co-curricular learning and engagement. Residence life staff may use NSSE data to assess how well their programs and facilities foster important forms of engagement, including course learning, social integration, experiences with diversity, and a supportive campus environment. The three figures below compare full-time, first-year students of traditional age (under 21) who live on campus with those living off campus on selected measures of engagement, diversity, and perceptions of the campus environment. Students classified as living on campus reported living in a "dormitory or other campus housing" or "fraternity or sorority house" while attending college.

Results from NSSE 2014 indicate that first-year students living on campus spent, on average, around two more hours per week than their off campus counterparts in each type of activity: preparing for class, participating in co-curricular activities, and relaxing and socializing (Figure 1).

Time spent in variosu activities by campus housing status

While first-year students living on and off campus had similar amounts of discussions with people of a different race or ethnicity, first-year students living on campus had more conversations with students with economic backgrounds, religious beliefs, and political views other than their own (Figure 2).

Discussions with Diverse Others by Campus Housing Status

Finally, on campus students, more than their peers who lived off campus, said their institution substantially emphasized providing support to succeed academically, providing opportunities to be involved socially, providing support for their overall well-being, and attending campus events and activities (Figure 3).

Perceptions of Institutional Emphasis by Campus Housing Status

For more information on these results and other ideas for connecting NSSE results to specific campus programs and units, see the Lessons from the Field and NSSE's Annual Results.

Kuh, G. D. (1996). Guiding Principles for Creating Seamless Learning Environments for Undergraduates. Journal of College Student Development, 37(2), 135-48.

*********************************************************.
****SPSS Syntax: Residence Life.
*********************************************************.

***The following syntax will work with NSSE data begining with the 2013 administration***.

***The example analysis used NSSE data from the 2014 administration***.

***Insert the directory path to your NSSE data file or open your NSSE data file manually***.
GET FILE = 'C:\nsse\nsse14.sav'.

***Selecting respondents that met NSSE eligibility and sampling criteria***.
***If your institution has a targeted oversample (sample = 4) or locally administered sample or oversample (sample = 5)
that you want to include in the analysis, change the value of 'sample' to match that criteria***.
SELECT IF (eligible = 1 AND sample LE 3).

***Recoding living into living on campus and living off campus***.
NUMERIC oncampus (F4.0).
RECODE living (1 THRU 2 =1) (3 THRU 5=0) INTO oncampus.
VARIABLE LABELS oncampus 'Student living on campus (collapsed recode of living)'.
VALUE LABELS oncampus 0 'No' 1 'Yes'.
EXECUTE.

***Recodes "Very often" and "Often" into "Frequently" and "Sometimes" and "Never" into "Infrequently"***.
RECODE DDrace DDeconomic DDreligion DDpolitical (1=1) (2=1) (3=2) (4=2) INTO xDDrace xDDeconomic xDDreligion xDDpolitical.
VALUE LABELS xDDrace xDDeconomic xDDreligion xDDpolitical
1 'Infrequently'
2 'Frequently' .
EXECUTE.

***Recodes "Very much" and "Quite a bit" into "Substantial" and "Some" and "Very little" into "Not substantial".
RECODE SEacademic SElearnsup SEdiverse SEsocial SEwellness SEnonacad SEactivities SEevents (1=1) (2=1) (3=2) (4=2) INTO
xSEacademic xSElearnsup xSEdiverse xSEsocial xSEwellness xSEnonacad xSEactivities xSEevents .
VALUE LABELS xSEacademic xSElearnsup xSEdiverse xSEsocial xSEwellness xSEnonacad xSEactivities xSEevents
1 'Not substantial'
2 'Substantial' .
EXECUTE.

***Selecting full-time, traditional age first-year students and running the time on task analysis***.
TEMPORARY.
SELECT IF (IRclass = 1 AND IRenrollment = 1 AND age LT 21).
MEANS TABLES=tmprephrs tmcocurrhrstmrelaxhrs BY oncampus
/CELLS MEAN.


***Selecting full-time, traditional age first-year students and running the engagement analysis***.
TEMPORARY.
SELECT IF (IRclass = 1 AND IRenrollment = 1 AND age LT 21).
CROSSTABS oncampus BY xDDrace xDDeconomic xDDreligion xDDpolitical
/CELLS COUNT ROW.

TEMPORARY.
SELECT IF (IRclass = 1 AND IRenrollment = 1 AND age LT 21).
CROSSTABS oncampus BY xSEacademic xSElearnsup xSEdiverse xSEsocial xSEwellness xSEnonacad xSEactivities xSEevents
/CELLS COUNT ROW.

 

Time Spent on Selected Activities by Related-Major Category

Understanding how students allocate their time among academic work, employment, and other activities and commitments offers insight into both student support needs and programmatic differences in expectations and requirements.

The figure below shows the average amount of time full-time seniors in NSSE 2014 spent on seven activities across ten categories of related majors (hours per week are estimated using the midpoint from the categorical response options). While seniors in different related-major categories spent their time in similar ways across a few activities (relaxing or socializing, co-curricular activities, and community service or volunteer work), they varied greatly in time spent preparing for class, ranging from 12 hours per week for communications, media, and public relations majors to 19 hours per week for engineering majors. Institutional users can reproduce this analysis using the SPSS syntax to produce the average amount of time seniors spent on various activities and input these numbers into the Excel graphing template to produce the graph below.

Time Spent by Full-Time Seniors on Select Activities by Related-Major Category

For more information on these results and other ideas for connecting NSSE results to specific campus programs and units, see Lessons from the Field and the 2011 NSSE Annual Results. See NSSE's ten related-major categories for a list of individual majors within each category.

*********************************************************.
****SPSS Syntax: Time Spent on Selected Activities.
*********************************************************.

***The following syntax will work with NSSE data begining with the 2013 administration***.

***The example analysis used NSSE data from the 2014 administration***.


***Insert the directory path to your NSSE data file or open your data file manually***.
GET FILE = 'C:\nsse\nsse14.sav'.

***Selecting respondents that met NSSE eligibility and sampling criteria***.
***If your institution has a targeted oversample (sample = 4) or locally administered sample or oversample (sample = 5)
that you want to include in the analysis, change the value of 'sample' to match that criteria***.
SELECT IF (eligible = 1 AND sample LE 3).

VARIABLE LEVEL tmprephrstmworkhrstmrelaxhrstmcocurrhrstmservicehrstmcommutehrstmcarehrs (SCALE).

***Selecting full-time seniors and running the time on task analysis***.
TEMPORARY.
SELECT IF (IRclass = 4 AND IRenrollment = 1).
MEANS TABLES = tmprephrstmworkhrstmrelaxhrstmcocurrhrstmservicehrstmcommutehrstmcarehrs BY MAJfirstcol
/CELLS MEAN.

***This analysis can also be run with the CTABLES command as follows***.
TEMPORARY.
SELECT IF (IRclass = 4 AND IRenrollment = 1).
CTABLES /TABLE MAJfirstcol BY ((tmprephrs + tmworkhrs + tmrelaxhrs + tmcocurrhrs + tmservicehrs + tmcommutehrs + tmcarehrs) [MEAN]).

***The syntax above runs on NSSE's standard major categories***..
***To run the analysis using your own grouping of majors, create a new variable and assign it specific majors***.
***For example, the syntax below creates a new variable, majorcat, and assigns English, French, and Spanish to category 1,
***Art and Art History to cateogry 2, Biology and Chemistry to category 3, and Mathematics and Physics to category 4.

NUMERIC majorcat (F4.0).
IF any(MAJfirstcode, 4, 5, 6) majorcat = 1.
IF any(MAJfirstcode, 1, 3) majorcat = 2.
IF any(MAJfirstcode, 16, 35) majorcat = 3.
IF any(MAJfirstcode, 38, 39) majorcat = 4.
VALUE LABELS majorcat 1 'Languages' 2 'Art' 3 'Biology & Chemistry' 4 'Math & Physics'.

***Run the time on task analysis with new categories of majors***.
TEMPORARY.
SELECT IF (IRclass = 4 AND IRenrollment = 1).
MEANS TABLES = tmprephrstmworkhrstmrelaxhrstmcocurrhrstmservicehrstmcommutehrstmcarehrs BY majorcat
/CELLS MEAN.

***The analysis can also be run using the CTABLES command***.
TEMPORARY.
SELECT IF (IRclass = 4 AND IRenrollment = 1).
CTABLES /TABLE majorcat BY ((tmprephrs + tmworkhrs + tmrelaxhrs + tmcocurrhrs + tmservicehrs + tmcommutehrs + tmcarehrs) [MEAN]).

Evidence-Based Improvement in Higher Education

Center for Postsecondary Research
Indiana University
School of Education
201 N. Rose Avenue
Bloomington, IN 47405-1006
Phone: 812.856.5824
Email: